VBA

VBAのWaitメソッドとは？メソッドの解説と使用例

ENGINEER.CLUB編集部

• 最終更新日:2024/9/1

VBAでマクロを作成しているときに、「特定の時間に処理を再開したい」「○秒後に処理を再開したい」と思ったことはありませんか？

時間を指定して処理を行う場合のマクロを作成する場合は、Waitメソッドを使用してみましょう。

１．Waitメソッドについて

１-１．Waitメソッドとは

実行中のマクロを指定した時刻まで停止し、指定した時刻になると処理を再開します。指定する時間は、「hh:mm:ss形式」で行います。似たような機能で、Sleep関数があります。Sleep関数については、下記リンクを参照してください。

VBAのWaitメソッドとは？メソッドの解説と使用例

 2024/09/01

１-２．Waitメソッドの構文

Waitメソッドの構文は下記の通りです。戻り値は、Boolean型（true：指定した時刻まで停止した、false：途中で強制終了した）です。

Application.Wait (再開する時刻)

１-３．Sleep関数との違い

Sleep関数とWaitメソッドとの違いは、下記の表にまとめています。

採用基準の一つとして、使用目的が「中断する時間」と「再開する時間」のどちらを目的とするかがあります。

２．Waitメソッドの使用例

２-１．基本的な使用例

２-１-１．再開時刻を指定する

「特定の時間まで処理を待機して、時間が来たら実行したい」場合は、下記のように指定します。

Sub sample01()

    Application.Wait TimeValue("17:00:00")	'17時に処理を再開

    MsgBox "17時になったので、処理を実行します。"	'処理例

End Sub

２-１-２．実行時から一定時間後を指定

停止する秒を指定して、時間が経過したら処理を再開したい場合は、下記のように指定します。

Sub sample02()

    Application.Wait (Now + TimeValue("0:00:05"))

    MsgBox "5秒経過したので、処理を再開します。"

End Sub

２-２．特殊な書き方をする場合

２-２-１．強制終了（中断中にESCボタン押下）したかをチェック

Waitの戻り値をチェックすることで、指定した時間を停止したかを確認することができます。

Sub sample03()

    If Application.Wait(Now + TimeValue("0:00:10")) = False Then
        MsgBox "強制停止しました。"
    Else
        MsgBox "10秒経過したので、処理を再開します。"
    End If

End Sub

２-２-２．ミリ秒を指定する場合

再開までの時間を、ミリ秒で指定することもできます。

Sub sample04()
    Dim ms As Long  'ミリ秒を格納
    ms = 10000    '停止させたい時間をミリ秒で指定

    Application.Wait (Now + ms / 86400000)

    MsgBox "10秒経過したので、処理を再開します。"

End Sub

３．注意点

下記のように、「Application.」をWaitの前に記述しないと、実行時にエラー

Sub sample05()
    
    Wait (Now + TimeValue("0:00:05"))	'「Application.」がWaitの前についていない

    MsgBox "5秒経過したので、処理を再開します。"

End Sub

エラー画像

４．最後に

WaitメソッドはSleep関数と処理は似ていますが設定する値の単位が異なるので、使用目的に応じて使い分けてください。